@echo off
setlocal EnableDelayedExpansion
REM Nauticus CLI continuous sync launcher for Windows
REM Place this file next to nauticus-cli.exe and a file named exactly .env

set "envFile=.env"

if not exist "%envFile%" (
  echo ERROR: No se encontro el archivo %envFile%
  echo.
  echo Copia .env.example a .env y rellena los valores reales del cliente.
  echo El archivo .env debe estar en la misma carpeta que este .bat
  pause
  exit /b 1
)

for /f "usebackq delims=" %%a in ("%envFile%") do (
  set "raw=%%a"
  set "line=!raw!"

  if "!line:~0,3!"=="" set "line=!line:~3!"

  for /f "tokens=*" %%b in ("!line!") do set "line=%%b"

  if not "!line!"=="" (
    if not "!line:~0,1!"=="#" (
      for /f "tokens=1* delims==" %%b in ("!line!") do (
        set "_name=%%b"
        set "_value=%%c"
        for /f "tokens=*" %%d in ("!_name!") do set "_name=%%d"
        if "!_value:~0,1!!_value:~-1!"=="\"\"" set "_value=!_value:~1,-1!"
        set "!_name!=!_value!"
      )
    )
  )
)

if "%TRITON_API_KEY%"=="" (
  echo ERROR: TRITON_API_KEY no esta configurada correctamente en .env
  echo.
  echo Contenido leido de .env:
  type "%envFile%"
  echo.
  echo Si usaste el Bloc de notas, prueba a crear el archivo desde cmd con:
  echo   echo TRITON_API_KEY=tu_clave ^> .env
  echo   echo FB_PASSWORD=tu_pass ^>^> .env
  pause
  exit /b 1
)

if "%FB_PASSWORD%"=="" (
  echo ERROR: FB_PASSWORD no esta configurada correctamente en .env
  echo.
  echo Contenido leido de .env:
  type "%envFile%"
  pause
  exit /b 1
)

echo ==> Iniciando sincronizacion continua
nauticus-cli.exe --sync